第２回メッセージによる制御構造１（4月20日）

今日の課題

コレクション（１）
インスタンス変数
ブロック
いわゆる if文、while文
コレクション（２）

■ コレクション（１）

複数のオブジェクトを束ね持つオブジェクトのことをコレクションという。オブジェクトを順に並べて束ね持つ場合は「配列(Array)」を使い、C言語でも良く使われる。順番に意味が無い場合は「Bag」というオブジェクトが便利である。

例題１

Bag に「星(StarMorph）」を３つ入れてみよう。Workspace上で以下を実行すればよい。

b := Bag new.
b add: (StarMorph new openInWorld position: 100@130).
b add: (StarMorph new openInWorld position: 95@100).
b add: (StarMorph new openInWorld position: 120@115)

■ インスタンス変数

例題２

１個以上の星の集りを表すクラス MyStars を作成しよう。このクラスは、 Bag のインスタンス stars に星を入れ、stars をインスタンス変数に持つ。つまり、以下のように定義する。

クラスの定義

Object subclass: #MyStars
    instanceVariableNames: 'stars'
    classVariableNames: ''
    poolDictionarys: ''
    category: 'MyObjects'

メソッドの定義

initialize
  stars := Bag new

appear: pos
  stars add: (StarMorph new openInWorld position: pos)

実行は、Workspace 上で以下を行う。

x := MyStars new initialize.
x appear: 300@300.
x appear: 310@320.
x appear: 320@290.
x appear: 325@270

■ ブロック

ブロックは、１個以上のステートメントを束ね持つオブジェクトである。大括弧で１個以上のステートメントを囲むことで表記する。C言語で、ステートメントを中括弧｛　｝で囲むことができるが、C言語は｛　｝を順番になると直に実行するが、Smalltalk では、動けと言われるまでは実行されず、何度も実行することができる。

例題３

下記を１行ずつ評価してみよう。

x := MyStars new initialize      （← ここを入力した後で Alt-d を押す）
y := [ x appear: 200@200. x appear: 210@220 ]      （← ここを入力した後で Alt-d を押す）
y value      （← ここを入力した後で Alt-d を押す）
y value      （← ここを入力した後で Alt-d を押す）

（ブロックには引数を渡すことができる。）

z := [: pos| x appear: (200 + pos)@(200 + pos). x appear: (210 + pos)@(220 + pos) ]
z value: 50
z value: 150

■ 制御構造

プログラムの制御は、以下のメッセージを送ることで実現される。

ifTrue:
ifFalse:
ifTrue:ifFalse:
whileTrue:
whileFalse:
repeat:

例題４

ifTrue: の使用例

( 100 < 200 ) ifTrue: [ x appear: 100@400 ]
( 100 > 200 ) ifFalse: [ x appear: 100@420 ]
( 100 > 200 ) ifTrue: [ x appear: 100@450 ] ifFalse: [ x appear:400@100 ]

whileTrue: の使用例（whileTrue: の左側がブロックであることに注意）

i := 1.
[ i < 10 ] whileTrue: [ x appear: 100@(i * 10 + 100). i := i + 1 ]

■ コレクション２

コレクションのテスト

たとえば、Bag に入っているものについて検査する。

size 個数を数える。
isEmpty からっぽならば true を返す。
includes:〈オブジェクト〉 〈オブジェクト〉が入っているならば true を返す。

コレクションへの操作

たとえば、Bag に入っているものの１個ずつについて何か操作する。

do: １個ずつの要素について、ブロックの処理を実行する。
collect: １個ずつの要素について、ブロックの処理を実行し、結果を集めたコレクションを返す。
select: １個ずつの要素について、ブロックの処理を実行し、結果が true になったときの要素を集めたコレクションを返す。
reject: select の逆で false のものを返す。
detect: １個ずつの要素について、ブロックの処理を実行し、結果が true になった最初の要素を返す。

例題５

Bag に積めた星を全て消してみよう。

b := Bag new.
b add: (StarMorph new openInWorld position: 100@130).
b add: (StarMorph new openInWorld position: 95@100).
b add: (StarMorph new openInWorld position: 120@115).
b do: [: s | s delete]

例題６

偶数のみを Transcript に表示しよう。

do: と ifTrue: を使う場合

#( 1 2 3 4 5 6 7 8 9 10 ) do: [: i | (i even) ifTrue: [Transcript show: i; cr]]

select: を使う場合

(#( 1 2 3 4 5 6 7 8 9 10 ) select: [: i | i even]) do: [: i | Transcript show: i; cr]

□ 第１回小レポート

MyStars に、次に説明する機能を持つメソッド deleteAll を追加せよ。

stars に入っている星の数を Transcript に表示する。
stars に含まれる星を全て消す。
消去後は、stars に空の Bag のインスタンスを代入する。

提出する小レポートには、Workspace 上で以下を実行した結果、および、 System Browser 上に deleteAll を表示した状態の画面を印刷して提出すること。

a := MyStars new initialize.
b := MyStars new initialize.
c := [:man :pos :i |
    [ i > 0 ]
        whileTrue: [ man appear: (i * 20)@pos.
                     i := i - 1 ]
    ].
c value: a value: 200 value: 10.
c value: b value: 300 value: 10.
a deleteAll

画面の取り込みは、Linux の画面の一番上のメニューバーの「アクション」を選択し、「スクリーンショット」を選択する。すると、Screenshot.png というファイルが作られる。

画面の印刷は、「gimp」などのグラフィックツールを使って印刷する。

伝達事項

小レポートの採点後は，いったん返却します．返却されたレポートは各自がファイルに綴じておいて下さい．最終レポートと同時にそのファイルを提出してもらいます．その後，ファイルは返却しません．

2005.4.13 by tokuhisa

第２回 メッセージによる制御構造１（4月20日）